MFA Basic - Info's zum Basic Interpreter

20 PRINT "23 MATCHES"
30 PRINT "CREATIVE COMPUTING, NEW JERSEY"
35 PRINT "MODIFIED BY PHILIP LORD FOR THE APPLE 1"
40 PRINT:PRINT:PRINT
80 PRINT "THIS IS A GAME CALLED '23 MATCHES'."
90 PRINT
100 PRINT "WHEN IT IS YOUR TURN, YOU MAY TAKE ONE,"
110 PRINT "TWO, OR THREE MATCHES. THE OBJECT OF "
120 PRINT "THE GAME IS NOT TO TAKE THE LAST MATCH."
130 PRINT
140 PRINT "LET'S FLIP A COIN TO SEE WHO GOES"
150 PRINT "FIRST. IF IT IS HEADS THEN I WIN"
155 PRINT "THE TOSS..."
155 PRINT
160 REM
165 N = 23
170 Q =RND(2)
180 IF Q = 1 THEN GOTO 210
190 PRINT "TAILS! YOU GO FIRST. "
195 PRINT
200 GOTO 300
210 PRINT "HEADS! I WIN! HA! HA!"
220 PRINT "PREPARE TO LOSE, MEATBALL-NOSE!!"
230 PRINT
250 PRINT "I TAKE 2 MATCHES"
260 N = N -2
270 PRINT "THE NUMBER OF MATCHES IS NOW "; N
280 PRINT
290 PRINT "YOUR TURN"
295 PRINT "YOU MAY TAKE 1, 2 OR 3 MATCHES."
300 PRINT "HOW MANY DO YOU WISH TO REMOVE"
310 INPUT K
320 IF K > 3 THEN GOTO 430
330 IF K <= 0 THEN GOTO 430
340 N = N - K
350 PRINT "THERE ARE NOW ";N;" MATCHES REMAINING."
351 IF N = 4 THEN GOTO 381
352 IF N = 3 THEN GOTO 383
353 IF N = 2 THEN GOTO 385
360 IF N <= 1 THEN GOTO 530
370 Z = 4 - K
372 GOTO 390
380 PRINT
381 Z = 3
382 GOTO 390
383 Z = 2
384 GOTO 390
385 Z = 1
390 PRINT "MY TURN! I REMOVE "; Z ;" MATCHES"
400 N = N - Z
410 IF N <= 1 THEN GOTO 470
420 GOTO 270
430 PRINT "VERY FUNNY! DUMMY!"
440 PRINT "DO YOU WANT TO PLAY OR GOOF AROUND?"
450 PRINT "NOW, HOW MANY MATCHES DO YOU WANT"
460 GOTO 310
470 PRINT
480 PRINT "SORRY! YOU TOOK THE LAST MATCH!"
490 PRINT "HA! HA! I BEAT YOU!!!"
500 PRINT
510 PRINT "GOOD BYE LOSER!"
520 GOTO 560
530 PRINT: PRINT "YOU WON, FLOPPY EARS!"
540 PRINT "THINK YOU'RE PRETTY SMART!"
550 PRINT: PRINT "LETS PLAY AGAIN (Y=1/N=0).": INPUT Y
555 IF Y=1 THEN GOTO 130
560 END

2 FOR A=1 TO 15
3 FOR B=1 TO 31
4 X=0
5 C=0
6 Y=0
7 FOR I=0 TO 11
8 C = (X*X)/10 - (Y*Y)/10 + (B-23)
9 Y = (X*Y)/5 + (10*A - 75)/8
10 X = C
11 IF (X/10)*X + (Y/10)*Y >= 400 THEN GOTO 15
12 NEXT I
13 PRINT "X";
14 GOTO 16
15 PRINT " ";
16 NEXT B
17 PRINT
18 NEXT A
19 END

10 REM (C)2019 PETER SIEG
20 PRINT "REVERSE AT POS UNTIL 1..9"
60 FOR I=1 TO 9
70 @(I)=I
80 NEXT I
90 GOSUB 500
100 REM SHUFFLE ROW
110 FOR I=1 TO 30
120 P=RND(8)+1:REM RANDOM 2-9
130 GOSUB 600
140 NEXT I
150 GOSUB 500
200 REM INPUT POS=P AND SHUFFLE AT P
210 INPUT "INPUT POSITION:",P
220 IF P<2 THEN GOTO 210
230 IF P>9 THEN GOTO 210
240 GOSUB 600:REM SHUFFLE AT P
250 GOSUB 500:REM PRINT ROW
260 GOSUB 400:REM CHECK IF ROW IS CORRECT
270 REM IF CORRECT P=0
280 IF P>0 THEN GOTO 200
290 PRINT "CORRECT!"
295 END
400 REM CHECK IF ROW IS CORRECT (1..9)
410 N=0
412 FOR I=1 TO 9
414 IF @(I)=I THEN N=N+1
416 NEXT I
418 IF N=9 THEN P=0
420 RETURN
500 REM PRINT NUMBER ROW
510 FOR I=1 TO 9
520 PRINT @(I);
530 NEXT I
540 PRINT
550 RETURN
600 REM SHUFFLE ROW AT POS P
610 GOSUB 700
612 IF P>3 THEN GOSUB 720
614 IF P>5 THEN GOSUB 730
616 IF P>7 THEN GOSUB 740
618 RETURN
700 REM EXCHANGE @(P) WITH @(1)
710 T=@(P)
712 @(P)=@(1)
714 @(1)=T
716 RETURN
720 REM EXCHANGE @(P-1) WITH @(2)
722 T=@(P-1)
724 @(P-1)=@(2)
726 @(2)=T
728 RETURN
730 REM EXCHANGE @(P-2) WITH @(3)
732 T=@(P-2)
734 @(P-2)=@(3)
736 @(3)=T
738 RETURN
740 REM ECHANGE @(P-3) WITH @(4)
742 T=@(P-3)
744 @(P-3)=@(4)
746 @(4)=T
748 RETURN