CPC 464 und Disketten

Psionfan_2005 · 8. März 2008

Hallo Leute,

im Recycling habe ich einen CPC464 plus Flobby gefunden.
Der CPC 464 scheint zu leben, nur hat er ab und zu ein Blackout.
(Dem werde ich mal bei Gelegenheit nachgehen...)
Das 3" Flobby war auch tot, per neuem Riemen konte ich ihm Leben einhauchen. 3x 3" Disketten (neu!! Dafür teuer!! ) konnte ich auch noch ergattern, nur waren diese damals ja unformatiert...
Wie kann ich nun diese Disketten Formatieren?
Ich habe einen CPC 464 und keine Systemdisketten.
Wie bekomme ich die Programme welche im Internet rumschwirren nun auf diese Disketten?? Tipps bitte.
Wer kann mir das ganz langsam und Schritt für Schritt erklären?
Oder kann ich Disketten per Basic formatieren???

Danke

Martin

Cash · 8. März 2008

Hallo erstmal und willkommen hier bei uns im Forum!

Auf dem CPC kannst du die Disketten mit den Systemdisketten formatieren (was ich noch nie getan hebe) oder mit einem Copierprogramm was auch formatieren kann (z.B. Discology).
Das müsstest du dir aber erstmal aus dem Netz saugen, es sind DSK formate.
Dann besorgst du dir CPCDiskXP von cpcmania, das installierst du auf deinem Windoof rechner. Da gibts auch eine datei dabei die musst du auch installieren damit der PC das CPC Disk Format erkennt, weiss aber nicht mehr wie die heisst, ist aber bei dem Programm dabei.
Dann nimmst du das Kabel an deinem 3" Laufwerk und schneidest die Nase am kabel die zum PC muss ab. Nun steckst du dein 3,5" bei dem Windoof PC ab und stecst stattdessen dass CPC Lufwerk dran, aber vorsicht es muss richtigrum drangesteckt werden, sonnst klappt es nicht.
Nun kannst du nach belieben Programme auf Disketten kopieren mit CPCDisk XP.
Das war meine Methode, gibt aber noch andere aber ich finde diese am besten.

Psionfan_2005 · 8. März 2008

Hallo Cash,

aha, so geht das.

Werde ich mal ausprobieren... :?

Danke.

Gruss

Martin

Anonymous · 8. März 2008

Format.bas benutzen

Code

10 SYMBOL AFTER 256:MEMORY &5FFF
20 FOR A=&7000 TO &7081
30 READ B$:POKE A,VAL("&"+B$):C=C+VAL("&"+B$)
40 NEXT
50 IF C<>13682 THEN PRINT"DATA ERROR":END
60 CALL &7000
70 DATA 01,0A,70,21,17,70,CD,D1,BC
80 DATA C9,0F,70,C3,1B,70,46,41,52
90 DATA 43,41,4C,CC,00,00,00,00,00,DD,7E
100 DATA 0A,32,7F,70,DD,7E,0B,32,80
110 DATA 70,DD,7E,08,32,81,70,DD,6E
120 DATA 00,DD,66,01,7E,DD,6E,02,DD
130 DATA 66,03,4E,23,46,DD,6E,04,DD
140 DATA 66,05,5E,23,56,D5,DD,6E,06
150 DATA DD,66,07,5E,23,56,62,6B,D1
160 DATA DD,E5,DF,7F,70,DD,E1,E5,DD
170 DATA 6E,00,DD,66,01,77,DD,6E,02
180 DATA DD,66,03,71,23,70,DD,6E,04
190 DATA DD,66,05,73,23,72,D1,DD,6E
200 DATA 06,DD,66,07,73,23,72,C9,00
210 DATA 00,00
220 MODE 1:BORDER 0:INK 0,0:INK 1,26:INK 3,6:PAPER 0:PEN 1:PLOT -10,-10,1
230 ENV 1,=11,10,=9,3000
240 DEFINT a-z
250 ORIGIN 0,200
260 FOR r=100 TO 380 STEP 7
270 MOVE r-7,r/4:DRAW r-3,r/8:DRAW r,0:DRAW r-3,-r/8:DRAW r-7,-r/4
280 NEXT
290 DRAW 93,-25:MOVE 93,25:DRAW 374,96
300 LOCATE 5,11:PRINT"0":LOCATE 24,6:PRINT"39":LOCATE 10,9:PRINT"10":LOCATE 15,8:PRINT"20":LOCATE 20,7:PRINT"30":LOCATE 1,1:PRINT"Select option":PRINT"1.Data Format":PRINT"2.System Format":PRINT"3.Exit"
310 i=VAL(INKEY$):IF i<1 OR i>3 THEN 310
320 SOUND 1,200,100,10,1
330 IF i=1 THEN f=&C1
340 IF i=2 THEN f=&41
350 IF i=3 THEN |BASIC
360 LOCATE 11,23:PRINT"Press F to Format":LOCATE 9,24:PRINT"Any other key to abort"
370 i$=UPPER$(INKEY$):IF i$="" THEN 370
380 IF i$<>"F" THEN 220
390 SOUND 1,150,100,10,1:LOCATE 11,22:PRINT SPACE$(70)
400 PLOT -10,-10,3
410 HL=0:DE=0:BC=0:A=0
420 POKE &6FFF,&83:HL=&6FFF
430 |FARCALL,&BCD4,0,@HL,@DE,@BC,@A
440 A=f:DE=0:|FARCALL,HL,7,@HL,@DE,@BC,@A
450 POKE &6FFF,&86:HL=&6FFF
460 |FARCALL,&BCD4,0,@HL,@DE,@BC,@A
470 HLT=HL
480 ADR=&6000
490 TRACK=0
500 FOR P=0 TO 9
510 POKE ADR,TRACK:POKE ADR+1,0:POKE ADR+2,f+P:POKE ADR+3,2:ADR=ADR+4
520 NEXT
530 DE=256*TRACK:HL=&6000:|FARCALL,HLT,7,@HL,@DE,@BC,@A
540 r=100+7*track:MOVE r-7,r/4:DRAW r-3,r/8:DRAW r,0:DRAW r-3,-r/8:DRAW r-7,-r/4
550 TRACK=TRACK+1:IF TRACK<40 THEN ADR=&6000:GOTO 500
560 SOUND 1,30,50,10,1:SOUND 1,30,100,10,1:LOCATE 12,22:PRINT"Format complete":LOCATE 13,23:PRINT"Press any key":WHILE INKEY$="":WEND:GOTO 220

Alles anzeigen

Viel Spass beim Abtippen

Psionfan_2005 · 8. März 2008

Funktioniert es unter WIN 95 mit Flobby?

Meine WIN XP Rechner haben keine FDD's mehr...

Psionfan_2005 · 8. März 2008

:? :? :? :?

per Basic klappt es nur mit tron....
hmmmm

Anonymous · 8. März 2008

Du brauchst das Programm eigentlich nur im CPC abzutippen.
Dann kannst du es starten und Deine Disks damit formatieren....

Psionfan_2005 · 9. März 2008

Hallo devil,

Programm klappt, aber leider irgend wie nur im TRON Modus....

Aber alle 3 Disk (x2) sind nun formatiert und lesbar....

DANKE..

Gruss

Martin

Anonymous · 9. März 2008

Zitat von "Psionfan_2005"

Programm klappt, aber leider irgend wie nur im TRON Modus....

Was passiert denn ohne TRON?
TRON zeigt doch nur die aktuellen Zeilennummern an....
Dürfte also auf das Programm keinerlei Einfluss haben.

Psionfan_2005 · 10. März 2008

ohne TRON (trace on) läuft das Programm bei mir nicht....

Sobald ich TRON eintippe, wird die Diskette formatiert und ist anschliessend per CAT sichtbar.

Mit TRON wird jeder Schritt gemacht und am Display angezeigt...

Dadurch ist scheinbar mein CPC langsam genug um die Formatierung zu machen.

Gruss

Martin