8085 Platinen wiederbeleben

Hallo liebe Leute,

ich habe eine alte völlig unbekannte 8085 Platine ins Leben geholt.

In diesem Thread möchte ich zeigen wie man ein 8085 System Testen und in gang kriegen kann.

Der Patien, eine 8085 Platine die weg geschmissen werden sollte, wurde von mir mit heim genommen um sie irgendwann zu richten.

Eigenbau Platine unbekannter Herkunft. Zweiseitige vermutlich selbst geätzte Platine, ohne Durchkontaktierung.

Siehe Mein neuestes Etwas, #11.205

Es ist ein 8085 Board, welches scheinbar nie fertig gebaut wurde.

Es könnte für irgend ein Schulungssystem gedacht gewesen sein.

Hier die Rückansicht.

Enthaltene Chips:

TMP8085AP, 8085 von Toshiba

EPROM 2716, Beschriftet: MON85

RAM HM6116, 2kB

1x MC1488 und 1x SN75189, d.h. RS232 Interface (benötigt +-12V)

Quarz 4,194MHz, gut für Badrate

Fehlende Chips:

links oben bei Taster, zunächst unbekannt, da steht lediglich 205

8755

8155

7406

74LS377

Nächste Schritte:

Schaltung ein "bischen" verstehen.

Spannung und Clock messen

Fehlende Chips einstecken

Hoffen und an RS232 lauschen, wenn es geht wäre es bereits langweilig.

EPROM Auslesen und weiter forschen.

Hier nun die Schritte die bis zur Funktion nötig waren:

Hilflsmittel:
-Lötausrüstung

-Messgerät

-Logikprüfstift

-Oszi

-Salea Logikanalyser (Chinaware), 8Kanal sowie 16Kanal

-Eprommer GALEP-III

1. Alles nachlöten, da im vorliegenden Fall einige Lötstellen nicht OK, waren. Anschließend wurden wichtige Verbindungen, durchgeklingelt.

2. Spannungspfade ohmisch durchgemessen.

3. Spannung eingeschaltet, nur 8085 war bestückt, Stromaufnahme war ca. 220mA

4. Mit Logikprüfstift, Reset und Clock auf Aktivität, bzw. Funktion geprüft.
Clock hat nicht funktioniert, Unterbrechung am Quarz in Ordnung gebracht, danach war Clock mit dem Prüfstift an Pin 2 (Quarz) und an Pin 37 Clk(Out) feststellbar. Ok, ich hab mir den Clock auch noch mit dem Oszi angesehen und die Frequenz gemessen. Quarz 4.193MHz, dieser wurde später gegen einen mit 6.144MHz getausch, dazu später.

5. Nun kam das EPROM und RAM mit auf die Platine und es wurde wieder eingeschaltet. Das EPROM wurde zuvor schon mal ausgelesen. FWT_85A_Mon85_2716.BIN, Im Hexdump des EPROMs war ein String enthalten "FWT-85A VER 3.0", dies ließ darauf schließen, das dieser String seriell ausgegeben wird. Es war auch eine RS232 Schnittstelle vorhanden, direkt über SOD und SID Pins des 8085 Prozessors.

6. Mit dem Logikstick wurde am SOD Ausgang (RS232 Ausgang) versucht Pulse zu sehen. Hierzu wurde mehrfach Reset betätigt, aber keine Aktivität.

7. Nun sollte noch ein Wenig die Schaltung verstanden werden. EPROM 2716 CE# hängt auf A11 Pin, CE# des RAM 6116 hängt über Inverter an Pin A11

D.h. EPROM von 0000...07FF, RAM von 0800...0FFF. OE# des EPROM und RAM hängen direkt am RD# Pin des 8085.

8. Jetzt hätte man mit dem Logik Analyser ran gehen können und versuchen zu verstehen was abläuft.

Weiterer Test mit Test EPROM mit Testprogramm:

.ORG 0000

loop:

jmp loop

Erwartung wenn dieses Program im EPROM gesteckt wird sollte nur das EPROM selektiert und gelesen werden.Test mit Prüftsift oder Oszi am CS# und OE# des EPROMs.

Ergebnis:

System verhielt sich chaotisch.

Jetzt wurde der Adress Latch 74LS373 näher angeschaut.

Da war der Pin11 G Eingang nicht am ALE Pin des 8085 sondern invertiert am ALE Pin angeschlossen, dies ist unüblich bzw. unsinnig. Der Pin11 wurde nun direkt mit ALE verbunden. Nun hat der Loop Test funktioniert.Indirekt gemessen mit Prüfstift, nur EPROM wurde selektiert.

Erster Erfolg, der Prozessor tut was er soll.

Jetzt kam das Original EPROM wieder rein, am SOD Ausgang (TXT) ware nun nach Reset Aktivität mit dem Prüfstift zu erkennen.Der Salea wurde nun benutzt um die seriellen Daten am SOD Ausgang zu analysieren und um die Baudrate zu messen. Aber alles was ich sah war Quatsch.FRaming Error, unsinnige Baudrate.

Fortsetzung im nächsen Block

...

Es soll nun erstmal ein EPROM Testprogrämmchen folgen welches eigentlich in jedem 8085 System funktionieren sollte.

;  TASM Assembler.           Version 3.2 September, 2001.
;  Copyright (C) 2001 Squak Valley Software
;  

0000             ;
0000             ; K.Loy, 8085 Board Test2
0000             ;
0000                       .ORG 0000h
0000             
0000             ;
0000             ; 8085 simple SOD clocking, without RAM
0000             ; 
0000 3E C0       loop:     mvi a,11000000b  ; SOD High
0002 30                    sim
0003 26 FF                 mvi h,255        ; loop counter      
0005 25          loop1:    dcr h
0006 C2 05 00              jnz loop1
0009 3E 40                   mvi a,01000000b  ; SOD LOW
000B 30                    sim  
000C 26 FF                 mvi h,255        ; loop counter      
000E 25          loop2:    dcr h
000F C2 0E 00              jnz loop2
0012 C3 00 00              jmp loop         ; endless loop
0015                   
0015                       .END
0015             
tasm: Number of errors = 0

Assembler:

Dieses Einfache Programm benötigt kein RAM welches ja evtl. nicht verfügbar ist oder nicht funtioniert. Das Programm gibt einfach endlos ein Rechtecksignal am SOD Ausgang des 8085 aus.
Quasi ein Blinky ohne LED.

Einfach das Prograsmm assemblieren und in ein EPROM brennen.
Rein stecken, einschalten, dann muss am SOD Ausgang, Pin4 des 8085 ein Rechecksignal erscheinen. Test am SOD mit Prüfstift, oder Oszi, Frequenz ca. 420Hz bei Clock 6.144MHz

Hiermit kann man leicht testen, ob ein 8085 sauber und dauerhaft ein EPROM Programm abarbeitet. RAM ist für diesen Test nicht nötig.

Um zu prüfen ob das RAM überhaupt geht müsste der Test erweitert werden.
Kommt vieleicht im nächten Block, ...

Schon mal vorab, das Board läuft bereits.
Aber ich möchte die Schritte dokumentieren vielleicht kanns ja jemand gebrauchen.

mfG. Klaus Loy

... es mach keinen Sinn diese Platine nachbauen zu wollen.
Eigentlich ist diese Platine ein ziemlicher Murx, doppelseitig, selbst geätzt, aber ohne Durchkontaktierung.
Da musst die Pins an den Fassungen von oben und von unten löten, furchtbar.
Aber das Ding hat mir damals so gut gefallen, so dass es nicht weg geworfen wurde.
Aber es war jetzt einges an Arbeit, es in Gang zu kriegen.
So konnte ich ein bisschen "Gefühl" für ein 8085 System bekommen und weiß nun wie das mit dem SOD und SID Pins des 8085 funktioniert.
Eigentlich hätte ich den Schaltplan der Platine aufnehmen können, aber für was, ...

Wenn du ein 8085 System bauen willst, dann nimm das MFA System,
oder sowas: Minimal 8085 Single Board Computer - MiniMax8085

Anmerkung:

Murx schreib ich Immer mit x, weils mir so besser gefällt.

mfG. Klaus Loy

Jetzt hab ich den Dowenload Link für den tasm (universal Assembler),

für die Win32 Version wieder gefunden: tasm32

Mit der anderen Version brauchte ich immer die DOSBox.

Und so läuft es unter Win7, bzw. Win10

mfG. Klaus Loy

...

und weil ich die Sache mit der seriellen Ausgabe über den SOD Pin nicht verstanden hab, und die Analyse des Bitstroms seltsam war wurde ein wenig der google befragt und auch die Doku zu meinem SDK-85 (welches übrigens auch nocht nicht funktionsfähig ist).

Die Sache mit dem SOD und SID ist gar nicht so schwierig.
Es muss halt das Bit Timing durch Warteschleifen erzeugt werden.
Und im SDK-85, Referenz Boards im Internet und auf einem anderem Board bei mir ist am 8085 ein Quarz mit 6.144MHz dran, bei meinem Patienten Board ist es 4,194MHz Quartz. Also kurz mal getausch und schon war die Bitbreite der SOD Impulse bei 416µs, was 2400Baud entspricht.

Nun wurde an das Board noch +-12V für die RS232 Treiber Chips angeschlossen und ein Kabel mit dem PC Com Port verbunden. Teraterm mit 2400Baud lieferte noch immer Quatsch.

Aber in der Zwischenzeit hatte ich die Seriellen Ein-/Ausgabefunktionen des 8085 aus dem SDK-85 Listing studiert.
Diese waren für 7Bit implementiert, war damals halt so üblich.
Also hab ich in Terraterm mal auf 2400,7Bit umgestellt und Bingo, nach Reset: ...

Boot_Message.PNG

so mag man das.

Jetzt wollt ich eben mal das Original EPROM mit dem Disassembler untersuchen, ...

Und was findet man da, genau die Ein-/Ausgaberoutinen aus dem SDK-85, ...

Also brauch ich gar nicht extra untersuchen welche Kommandos es gibt.
Die sind evtl. auch aus dem SDK-85 übernommen.

Display Memory Command, D: D<low address>,<high address>

... und genau so funktioniert es auch beim FWT-85A VER 3.0 Monitor

Ok, wieder ein kleines Spielzeug, repariert, bzw. ins Leben gebracht und z.T. verstanden.
Schöne Zeitverschwendung.

mfG. Klaus Loy

... wie ist das nun mit diesen 8085 SOD und SID Leitungen ?
Da gibt es eine application note ap-29 von Intel, bei Bitsavers.

Für SOD gibt es folgendes Bild:

(Quelle: https://www.geeksforgeeks.org/…s-in-8085-microprocessor/)

pasted-from-clipboard.png

Bit6 im Akku enabled die Beeinflussung des SOD Ausgangs.
Bit7 definiert den Pegel der durch den SIM Befehl gesetzt wird.
Beispiel:

; SOD wird gesetzt

MVI A,11000000b

SIM

; SOD wird gelöscht

MVI A,1000000b

SIM

Schaun wir uns den Code für die serielle Ausgabe an:

;
; CO Print Character in Reg C
;
CO:
    di               ; disable interrupt
    push   b         ; save registers
    push   d
    mvi    a,0C0H    ; start bit mask for sim operation
    mvi    b,007H    ; bit counter, for 7Bit ASCII
CO01:
    sim              ; SIM 11000000, Send a Bit
    lxi    d,00032H  ; Load Delay loop counter
    call   DELAY     ; Delay, wait one Bit Time
    mov    a,c       ; pick up bits left vto send
    rar              ; low order bit to carry
    mov    c,a       ; put rest back
    mvi    a,080H    ; shifted enable bit
    rar              ; shift in data bit
    xri    080H      ; complement data bit
    dcr    b         ; decrement bit counter
    jp     CO01      ; send if more bits need to be send
    mvi    a,040H    ; else, send stop bit
    sim               
    lxi    d,00064H  ; wait out parity bit and stop bit
    call   DELAY     ; Delay
    pop    d
    pop    b         ; restore registers
    ei               ; enable interrupts
    ret              ; finsished

;
; DX: Delay_Counter
;
DELAY:
    dcx    d       ; decrement DX-Register
    mov    a,d     ; 
    ora    e       ; check if zero 
    jnz    DELAY   ; if not next loop
    ret

Für SOD gibt es folgendes Bild:

(Quelle: https://www.geeksforgeeks.org/…s-in-8085-microprocessor/)

pasted-from-clipboard.png

Schaun wir uns den Code für die serielle Eingabe an:

;
; CI Reads a character from the serieal interface, Pin SID
;
CI:
    di                 ; disable interrupt
    push   d           ; save registers
CI05:
    rim                ; get input bit from SID pin 
    ral                ; into carry with it
    jc     CI05        ; branch if no start bit
    lxi    d,00018H    ; wait until middle of next bit
    call   DELAY       ; wait delay
    push   b           ; save BC
    lxi    b,8         ; B<--0; C<--Bits to receive
CI10:
    lxi    d,00032H    ; Wait until middle of next bit
    call   DELAY       ; wait delay
    rim                ; get input bit from SID pin 
    ral                ; put it into carry
    mov    a,b         ; get partial result
    rar                ; shift in next data bit
    mov    b,a         ; replace result
    dcr    c           ; decrement count of bits to go
    jnz    CI10        ; branch if more left
    lxi    d,00032H    ; else, want to wait out stop bits 
    call   DELAY       ; wait delay
    mov    a,b         ; get result to A
    pop    b  
    pop    d           ; restore registers
    ei                 ; enable interrupts
    ret                ; that's it

Mehr Erklärung gibt es nicht.

mfG. Klaus Loy

@ThoralfAsmussen,

du sollst deine Fotos bekommen.

Das ist doch so ein Verhau, wie willste das nachbauen.
Wenn, dann muss man das neu machen, schön mit KiCad, notfalls wird dir geholfen.
Es gibt hier sicher einige KiCad Experten.

Falls du eine Platine selbst entwerfen willst, doppelseitig ok, aber bitte keine "Durchkontaktierung" mit den Pins der Fassungen ralisieren. Weil sonst kannst das Zeug nicht vernünftig löten. Besser ein einfaches 8085 System frei verdrahten. Oder Platine machen lassen.

Übrigens das IC oben links, vermutlich ein 74138 hab ich nicht näher untersucht, auch die beiden ICs 8755 und 8155 hab ich in die Platine nicht eingesetzt, weil ich sie nicht brauche. Die Adressdekodierung der beiden Speicher ist super simpel, einfach A11 auf CE# EPROM und A11 über IOnverter auf CE# RAM, fertig.

Jetzt hatte ich schon ein wenig Angst, dass ich Kontaktprobleme mit den "Fassungen" bekomme, aber nein, das Board funktioniert wieder.

mfG. Klaus Loy

Das NKC Board hab ich auch fda liegen, vieleicht löt ich das mal zusammen.
Und dann hab ich noch zwei alte 8085 Boards hier liegen und meinen SDK-85, der ja auch nicht geht.
Es wird nich langweilig

... da wären nun nochmal zwei 8085 Platinchern welche auch wieder belebt werden möchten.

Das ist ein Controllerboard aus einem B-Netz Autotelefon, es konnte vor der Verschrottung gerettet werden.

pasted-from-clipboard.png

In so einer Steuerbox war das mal eingebaut.

Ich hab es nur deshalb mit genommen und somit gerettet, weil die Chips so nett aussehen.

mfG. Klaus Loy

... und hier das andere Board, herkunft unklar, vermutlich ein Trödelmarkt.

Hier die Vorderansicht

und da die Rückansicht.

Wenn jemand dieses Board kennt und Info hat, bitte schicken.

mfGF. Klaus Loy

einfach cool, mein SOD Pulser Test EPROM hat grade eben schon gute Dienste geleistet.

Einfache kurze Tests am TeKaDe Board:

Spannung 5V OK

Clock OK

Reset nicht getestet.

EPROM Ansteuerung von links nach rechts: CE# bei allen LOW, OE# bei allen HIGH

d.h. kein einziges EPROM wird angesteuert.
Test "wie immer" mit Logikprüfstift, da Easy Doing, und weil mein Stift Pulse anzeigen kann.

Also hab ich mein Test EPROM in "Slot 1" gesteckt links, Ergebnis, keine Aktivität.

Ursache: Der EPROM Slot1 ist rechts, also der vierete Sockel, welcher unbestückt war.

Also Test EPROM "SOD Clocker" in den rechten Slot, Power Off / On.

Ergebnis: OE# des EPROMs zeigt Aktivität.

Und vor allem der SOD zeigt Impulse, welche vom Testprogramm erzeugt werden.

Board lebt, SOD taktet

Also ist dieses Test Tool ein simples Tool um zu sehen, ob ein 8085 vom EPROM "arbeiten" kann.Wie gesagt RAM wird hier gar nicht getestet.

Bei dem vorliegenden Board liegt das einzige RAM im 8155 Chip.
Da müsste man jetzt die Adressdekotierung erstmal untersuchen, dann könnte man ein kleines Test oder Monitorprogramm schreiben. Die serielle Ein-/Ausgabe würde man dann über den 8251 UART laufen lassen.

Das ist aber aktuell nicht das Ziel.
Ich wollte nur sehen ob das Board überhaupt was tut.

mfG. Klaus Loy

Quote from Shadow-aSc

ah - ich ahne, wo du den Quarz für dein erstes Projekt her hattest

@Shadow-aSc, gut beobachtet.

Ich hatte tatsächlich keine solchen Quarz, aber es wurden gleich bei ebay welche bestellt.
Man braucht das ja so häufig, zumindest wenn man mit solchem 8085 Boards rum macht.

Was ist eigentlich auf den MFA Boards für ein Quarz drauf ?
Musst aber jetzt nicht nachschaun.

Die standard MFA CPU-Platine betreibt ja die RS232 Schnittstelle auf über die SOD und SID Pins.

mfG. Klaus Loy

@tokabln,

stimmt, war grad im Keller, 1. weil da mein MFA steht, hab gleich mal die CPU Platine gezogen, ist ein 4MHz drauf.
Man müsste mal schaun, wie das mit der Baudrate ist, wie genau die hinkommt mit 4MHz oder mit 4.144MHz.
Ok wenn es über SOD und SID geht, dann laufen da ja Softwarewarteschleifen.

Die MFA CPU Platine macht ja am Anfang diese automatische Baudratenerkennung des Terminals.

Anders bei den UARTs, da wird ja die Baudrate ganzahlig runter geteilt.

Da braucht man dann die ungeraden Quarz Frequenzen wenn man es richtig machen will.

2. war ich im Keller weil da noch so eine alte gerettete Platine lag, wo auch ein 8085 Prozessor drin steckt. Foto im nächsten Block.

mfG. Klaus Loy

... wie angedroht, hier noch eine 8085 Platine. Die wurde aus einem HF-Messgerät entnommen, welches verschrottet wurde.

Mal schaun, ob das Board noch läuft. Etstmal auch wieder der SOD rein, aber leider ist da kein 2716er drauf.
Muss ich erst einen 2732er brennen.

mfG. Klaus Loy