Hallo Leute,
Ihr kennt sicherlich 'Kaiser' von Ariolasoft...
Heute habe ich dank VooDoo eine Kaiser-Fassung gefunden, die weitgehend unbekannt sein dürfte.
Dieses Spiel ist (auch) komplett in BASIC programmiert.
Auch sie macht Laune zu spielen.
Hier das BASIC Listing zum Abtippen:
Code
1 MODE 1
2 KEY 139,"mode 2:pen 1:list "
3 KEY 140,"mode 1:run 59"+CHR$(13)
10 INK 2,2:INK 3,9
20 CLS
30 BORDER 0
40 INK 0,0
49 LOCATE 17,8:PRINT"Promotion"
50 FOR a=1 TO 250
51 PLOT 320,160
52 aaA=INT(RND*3)+1
53 DRAW 320+100*COS(a),160+50*SIN(a),aaa
54 DRAW 320+50*COS(a),160+100*SIN(a),aaa
55 NEXT
56 zz=INT(RND*26)+1
57 zzz=INT(RND*3)+1
58 INK zzz,zz
59 a$=INKEY$:IF a$=""THEN 56
80 INK 2,2:INK 3,9:INK 1,24:CLS
90 FOR a=1 TO 16
100 READ a$
110 NEXT a
120 PRINT"Geben sie bitte die Anzahl der Mitspieler ein [1-6]"
130 a$=INKEY$:IF a$=""THEN 130
160 f=VAL(a$)
170 IF f<1 OR f>6 THEN CLS:GOTO 120
180 FOR a=1 TO f
190 READ t$(a)
200 CLS
210 PRINT"Wer ist Herrscher von "t$(a)
220 INPUT n$(a)
230 n$(a)=n$(a)+" von "+t$(a)
240 CLS
250 PRINT"ist "n$(a)
260 PRINT"Maennlich oder Weiblich?"
270 v(a)=0
280 a$=INKEY$:IF a$=""THEN 280
300 IF a$<>"m" AND a$<>"w"THEN GOTO 280
310 IF a$="w" THEN v(a)=8:sw(a)=1
320 h(a)=10
330 g(a)=25
340 i(a)=5
350 j(a)=2
360 O(a)=1420+INT(RND+35)
370 k(a)=2500
380 l(a)=10000
390 r(a)=5000
400 t(a)=1
410 u(a)=1
420 n(a)=4
430 p(a)=25
440 q(a)=5
450 m(a)=25
460 s(a)=2000
470 NEXT
480 FOR a=1 TO f
490 RESTORE
530 b=v(a)+t(a)
540 FOR c=1 TO b
550 READ t$(a)
560 NEXT c
570 NEXT a
580 PRINT: PRINT"Es gibt 4 verschiedene Haertegrade"
590 PRINT"in Bezug auf die Wertung."
600 PRINT"Waehlen sie einen zwischen 1 und 4"
610 a$=INKEY$:IF a$=""THEN 610
615 ff=VAL(a$)
620 IF ff=1 THEN le=le+1:GOTO 650
630 IF ff=2 THEN le=le+2:GOTO 650
635 IF Ff=3 THEN le=le+3:GOTO 650
640 IF ff=4 THEN le=le+4:GOTO 650
645 GOTO 600
650 REM
660 e=e+1
670 IF t(e)=-1 THEN e=e+1
680 IF e>f THEN e=0:y(o)=y(o)+1:GOTO 650
690 IF y(o)>o(e) THEN 660
700 REM ************************************************getreidehaushalt
710 w=INT(RND*5)+INT(RND*6)/2+1
720 ON w GOTO 730,750,770,790,810
730 w$="Trockenheit-Boden verdorrt "
740 GOTO 820
750 w$="Unguenstigen Witterung-Miese Ernte"
760 GOTO 820
770 w$="Maessiges Wetter-Maessige Ernte"
780 GOTO 820
790 w$="Gutes Wetter-Gute Ernte"
800 GOTO 820
810 w$="Optimales Wetter-Ausgezeichnete Ernte"
820 r=INT(RND*50)
830 r(e)=(r(E)*100-r(e)*r)/100
840 x=l(e)
850 y=(s(e)-d(e)*100)*5
860 IF y<0 THEN y=0
870 IF y<x THEN x=y
880 y=r(e)*2
890 IF y<x THEN x=y
900 r(e)=r(e)-x/2
910 y=w-0.5
920 h=x*y
930 r(e)=r(e)+h
940 REM ************************************************Getreidehaushalt
950 d=n(e)*100+c(e)*40+m(E)*30+p(e)*10+s(e)*5
960 l=(3*w+INT(RND*6)+INT(RND*6)+10)/10
970 IF w=1 THEN l=l-1
980 IF h<1 THEN y=2:GOTO 1030
990 y=d/h
1000 IF y>2 THEN y=2
1010 IF y<0.8 THEN y=0.8
1020 l=l*y
1030 l=INT(l*10)
1040 l=l/10
1050 REM ***********************************************Preis fuer Getreide
1060 z=6-w
1070 g=(z*3+INT(RND*5)+INT(RND*5))/5*y*20
1072 IF g<= 0 THEN g=1
1080 CLS
1090 LOCATE 10,1:PRINT"Getreidehaushalt:"
1100 PRINT
1110 PEN 3:PRINT t$(e);" ";n$(e):PEN 1
1120 REM ****************************************************** Bildschirmmaske
1130 PRINT"Das ist das Jahr "y(o)" Ihrer Herrschaft."
1140 PRINT"Es verschimmeln " r"% Ihrer Vorraete"
1150 PRINT w$
1160 PRINT"(" h" KG)"
1170 PRINT:PRINT"Kornvorraete:........"
1180 LOCATE 22,9:r(e)=INT(r(e)):PRINT r(e)
1190 LOCATE 34,9:PRINT"KG"
1210 PRINT
1220 PRINT"Kornnachfrage:........"
1230 LOCATE 22,11:PRINT d
1240 LOCATE 34,11:PRINT"KG"
1250 PRINT
1260 PRINT"Kornpreis:..........."
1270 LOCATE 22,13:PRINT g
1280 LOCATE 34,13:PRINT"Knetis"
1290 PRINT
1300 PRINT"Landpreis:..........."
1310 LOCATE 22,15:PRINT l
1320 LOCATE 34,15:PRINT"Knetis"
1330 PRINT
1340 PRINT"Vermoegen:..........."
1350 LOCATE 22,17:K(e)=INT(k(e)):PRINT k(e)
1360 LOCATE 34,17:PRINT"Knetis"
1370 PRINT
1380 LOCATE 10,19:PRINT"Sie koennen: 1=Korn kaufen"
1390 LOCATE 23,20:PRINT"2=Korn verkaufen"
1400 LOCATE 23,21:PRINT"3=Land kaufen"
1410 LOCATE 23,22:PRINT"4=Land verkaufen"
1420 LOCATE 10,23:PRINT"Ihre Wahl???";
1430 a$=INKEY$:IF a$=""THEN 1430
1450 i=VAL(a$)
1460 IF i>0 AND i<5 THEN 1480
1470 GOTO 1760
1480 ON i GOTO 1490,1550,1620,1680
1490 GOSUB 4820
1500 LOCATE 1,24:INPUT"Wieviel Korn wollen sie Kaufen";i
1520 k(e)=k(E)-(i*g/1000)
1530 r(e)=r(e)+i
1540 GOTO 1080
1550 GOSUB 4820
1560 LOCATE 1,24:INPUT"Wieviel Korn wollen sie verkaufen";i
1580 IF i>r(e)THEN LOCATE 1,24:PRINT"So viel besitze ich nicht!":FOR a=1 TO 999:NEXT:GOTO 1550
1590 k(e)=k(e)+(I*g/1000)
1600 r(E)=r(E)-i
1610 GOTO 1080
1620 GOSUB 4820
1630 LOCATE 1,24:INPUT"Wieviel Hektar wollen sie kaufen";i
1650 l(e)=l(e)+i
1660 k(e)=k(E)-(i*l)
1670 GOTO 1080
1680 GOSUB 4820
1690 LOCATE 1,24:INPUT"Wieviel Hektar wollen sie verkaufen";i
1710 IF i>(l(e)-5000) THEN PRINT"Wo sollen ihre Bauern denn leben?":FOR a=1 TO 999:NEXT
1720 IF i> (l(e)-5000) THEN GOTO 1080
1730 l(e)=l(e)-i
1740 k(e)=k(e)+(i*l)
1750 GOTO 1080
1760 REM *********************************************Bevoelkerungsberechnung
1770 g=r(e)-r(e)/5-1
1780 CLS
1790 PEN 3:PRINT:PRINT t$(e)" " n$(e):PEN 1
1800 PRINT:PRINT"Wieviel Korn darf das Volk"
1810 PRINT"verbrauchen (Max. " g")";
1820 INPUT g
1830 IF g< (r(e)/5)THEN PRINT"Wer wird denn Knausern?":FOR a=1 TO 700:NEXT:GOTO 1770
1840 IF g> (r(e)-(r(e)/5))THEN PRINT"Nicht uebertreiben!":FOR a=1 TO 700:NEXT:GOTO 1770
1850 r(e)=r(E)-g
1860 CLS
1870 LOCATE 10,1:PRINT"Bevoelkerungsbilanz:"
1880 PEN 3:PRINT:PRINT t$(e)" " n$(e):PEN 1
1890 PRINT
1900 z=g/d-1
1910 IF z>0 THEN z=z/2
1920 IF z>0.25 THEN z=z/10+0.25
1930 z%=50-g(e)-h(e)-i(e)
1940 IF z%<0 THEN z%=z%*J(E)
1950 Z%=Z%/10
1960 IF z%>0 THEN z%=z%+3-j(e)
1970 z=z+(z%/10)
1980 IF z>0.5 THEN z=0.5
1990 IF g<d-1 THEN 2380
2000 z=INT(RND*7)*s(e)/100
2001 IF z> 32000 THEN z=32101
2010 z%=z
2020 PRINT
2030 PRINT"Geburten/Jahr..............."z%
2040 s(e)=s(E)+z%
2050 z=INT(RND*3)*s(E)/100
2060 z%=z
2070 PRINT
2080 PRINT"Sterbefaelle/Jahr..........."Z%
2090 s(e)=s(E)-z%
2100 IF g(e)+h(E)<35 THEN m(e)=m(e)+INT(RND*4)
2110 IF i(e)<INT (RND*20) THEN n(e)=n(E)+INT(RND*2)-1
2120 IF i(e)<INT (RND*20) THEN q(e)=q(E)+INT(RND*3)-1
2130 IF g<d+d*0.3 THEN GOTO 2300
2140 z%=s(E)/1000
2150 z=(g-d)/d*10
2160 z=z*z%*INT(RND*25)+INT(RND*40)
2170 IF z>32000 THEN z=32000
2180 z%=z
2190 z=INT(RND*z%)
2200 PRINT
2210 PRINT"Einwanderungen.............."Z
2220 s(e)=s(e)+z
2230 u(e)=u(e)+0.5
2240 z%=z/5
2250 z=INT(RND*z%)
2260 IF z>50 THEN z=50
2270 mm(e)=m(e)+z
2280 n(e)=n(E)+1
2290 q(e)=q(e)+2
2300 REM ******************************************************** harte Justiz
2310 IF j(e)<3 THEN GOTO 2370
2320 j=s(e)/100*(j(e)-2)*(j(e)-2)
2330 j=INT(RND*j)
2340 s(e)=s(e)-j
2350 PRINT
2360 PRINT"Auswanderungen wegen Justiz."INT(j)
2370 GOTO 2570
2380 REM ********************************************************* Hungersnot
2390 x=(d-g)/d*100-9
2400 x%=x
2410 IF x>65 THEN x=65:M(e)=m(e)/2
2420 IF x<0 THEN x%=0:x=0
2430 a=3
2440 z=INT(RND*3)*s(e)/100
2450 z%=z
2460 PRINT
2470 PRINT"Geburten...................."z%
2480 s(e)=s(E)+z%
2490 a=x%+8
2500 z=INT(RND*a)*s(e)/100
2501 IF z>32000 THEN z=32000
2510 z%=z
2520 PRINT
2530 PRINT"Sterbefaelle wegen Hunger..."z%
2540 s(e)=s(E)-z%
2550 IF z%>1000 THEN u(e)=u(e)/2
2560 GOTO 2300
2570 REM *********************************************************Geldbilanz
2580 z=a(e)*75
2590 k(e)=k(e)+z
2600 IF z>0 THEN PRINT:PRINT"Miete (Markt)/Knetis........"z
2610 IF s(e)<32766 THEN s(E)=INT(s(E))
2620 z=d(E)*(55+INT(RND*250))
2630 IF z>0 THEN k(e)=k(e)+z:PRINT
2640 IF z>0 THEN PRINT"Fabrik (Gewinn)/Knetis......"z
2650 z=p(e)*3
2660 PRINT
2670 k(e)=k(E)-z
2680 PRINT"Sold (Soldaten)/Knetis......"z
2690 REM ******************************************************Zu wenig Soldaten
2710 IF l(E)/500<p(e)THEN 2760
2720 FOR a=1 TO f
2730 IF a=e THEN 2750
2740 IF p(a)>p(e)*2.4 THEN GOSUB 4860
2750 NEXT a
2760 PRINT
2770 PRINT"Weiter ? Taste!"
2780 a$=INKEY$:IF a$=""THEN 2780
2790 IF l(e)/1000>p(e)THEN GOSUB 4860
2810 REM ****************************************************Steuerberechnung
2820 CLS
2830 PRINT
2840 PEN 3:PRINT:PRINT t$(e)" " N$(e):PEN 1
2850 j=(j(e)*300-500)*t(e)
2860 ON j(e)GOTO 2870,2890,2910,2930
2870 j$="Harmlos"
2880 GOTO 2950
2890 j$="Normal"
2900 GOTO 2950
2910 j$="Streng"
2920 GOTO 2950
2930 j$="Scharf"
2940 GOTO 2950
2950 y=150-g(e)-h(e)-i(e)
2960 IF y<1 THEN y=1
2970 REM **********************************************************Einnahmen
2980 c=(n(e)*180+q(e)*75+m(e)*20)*(y/100)+u(e)*100
2990 s=(n(e)*50+m(e)*75+u(e)*10*(y/100)*5-j(e)/2)
3000 i=n(e)*250+u(e)*20+(10*j(e)*n(e))*(y/100)
3010 c=c*g(e)/100
3020 IF c<32760 THEN c=INT(c)
3030 s=s*h(e)/100
3040 IF s<32760 THEN s=INT(s)
3050 i=i*i(e)/100
3060 IF i<32760 THEN i=INT(i)
3070 LOCATE 10,1:PRINT"Steuerhaushalt"
3080 PRINT
3090 PRINT
3100 PRINT
3110 PEN 2:PRINT"Steuereinnahmen: "J+c+s+i" Knetis":PEN 1
3120 PRINT
3130 PRINT"Zoll/Prozent............"G(e)" " c" Kn."
3140 PRINT
3150 PRINT"Mehrwertsteuer/Prozent.."h(e)" " s" Kn."
3160 PRINT
3170 PRINT"Einkommensteuer/prozent."i(e)" " i" Kn."
3180 PRINT
3190 PRINT"Justiz.................." J$" " j" Kn."
3200 PRINT
3210 PRINT"Aenderungen (Nr. der Steuer eingeben)"
3220 a$=INKEY$:IF a$=""THEN 3220
3240 i=VAL(a$)
3250 PRINT
3260 IF i>4 THEN GOSUB 4820:GOTO 2820
3270 IF i< 1 THEN 3530
3280 ON i GOTO 3290,3350,3400,3450
3290 PRINT
3300 INPUT"Neuer Zollsatz [0-100]";i
3310 IF i>100 THEN i=100
3320 IF i<0 THEN i=0
3330 g(e)=i
3340 GOTO 2820
3350 PRINT
3360 INPUT"Neue Mehrwertsteuer [0-50]";i
3370 IF i>50 OR i<0 THEN i=5
3380 h(e)=i
3390 GOTO 2820
3400 PRINT
3410 INPUT"Einkommensteuer [0-25]";i
3420 IF i<0 OR i>25 THEN i=0
3430 i(e)=i
3440 GOTO 2820
3450 PRINT
3460 PRINT"Justiz:1=Harmlos 2=Normal 3=Streng 4=scharf?";
3470 a$=INKEY$:IF a$=""THEN 3470
3490 i=VAL(a$)
3500 IF i>4 OR i<1 THEN i=1
3510 j(e)=i
3520 GOTO 2820
3530 k(e)=k(e)+c+s+i+j
3540 REM ******************zinsen
3550 IF k(e)<0 THEN k(e)=k(e)*1.5
3560 IF k(e)<-10000*t(e)THEN GOSUB 5140
3570 REM *******************************************************Investionen
3580 CLS
3590 PEN 3:PRINT t$(e)" "n$(e):PRINT:PEN 1
3600 PRINT"Sie koennen in alle folgenden Dinge"
3610 PRINT"investieren:"
3620 PRINT
3630 PRINT"1.Markt [1000 Knetis]"
3640 PRINT
3650 PRINT"2.Fabrik [2000 Knetis]"
3660 PRINT
3670 PRINT"3.Residenz (Teilbau) [3000 Knetis]"
3680 PRINT
3690 PRINT"4.Kirche (Teilbau) [5000 Knetis]"
3700 PRINT
3710 PRINT"5.Eine Kompanie Soldaten ausruesten (20 Mann) [500 Knetis]"
3730 PRINT
3740 PRINT"6.Krieg fueren [1000 Knetis]"
3750 PRINT:PEN 2:PRINT"Sie besitzen" k(e)" Knetis":PEN 1
3760 IF k(e)<-30000 THEN GOSUB 5140
3770 PRINT
3780 PRINT"7.Anzeigen des Spielstandes"
3790 PRINT:PRINT"Weiter ? Taste!"
3800 a$=INKEY$:IF a$=""THEN 3800
3820 i=VAL(a$)
3830 IF i=6 THEN 6000
3831 IF i=7 THEN 5330
3840 ON i GOTO 3860,3910,3950,4000,4050
3850 GOTO 4090
3860 a(E)=a(e)+1
3870 m(e)=m(e)+5
3880 k(e)=k(e)-1000
3890 u(e)=u(e)+0.1
3900 GOTO 3570
3910 d(e)=d(E)+1
3920 k(e)=k(E)-2000
3930 u(e)=u(e)+0.25
3940 GOTO 3570
3950 b(e)=b(e)+1
3960 n(e)=n(e)+INT(RND*2)
3970 k(e)=k(e)-3000
3980 u(e)=u(e)+0.5
3990 GOTO 3570
4000 c(e)=c(e)+1
4010 q(e)=q(e)+INT(RND*6)
4020 k(e)=k(e)-5000
4030 u(e)=u(e)+1
4040 GOTO 3570
4050 p(e)=p(e)+20
4060 s(e)=s(e)-20
4070 k(e)=k(E)-500
4080 GOTO 3570
4090 REM******************************************************** Titelberechnung
4100 GOTO 7000
4480 IF t(e)=8 THEN GOTO 4540
4490 CLS
4500 PRINT"Sie wurden befoerdert und duerfen sich nun "T$(e)" nennen!"
4510 FOR x=1 TO 2121
4520 NEXT x
4530 GOTO 660
4540 CLS
4550 PRINT
4560 PRINT
4570 PRINT"Das Spiel ist nun zu Ende!"
4580 PRINT
4590 PRINT"Der Spieler "n$(e)" hat "
4600 PRINT"den hohen Rang des Kaisers erreicht !!"
4610 PRINT"um ein neues Spiel zu beginnen,gib eine 1 ein"
4620 PRINT"um das Spiel zu beenden,gib eine 2 ein"
4630 PRINT
4640 PRINT"um den Spielstand zu sehen,gib eine 3 ein"
4650 a$=INKEY$:IF a$=""THEN 4650
4670 a=VAL(a$)
4680 IF a>3 OR a<1 THEN a=2
4690 ON a GOTO 4700,4710,4740
4700 RUN
4710 CLS
4720 PRINT:PRINT"Auf Wiedersehen!":END
4740 GOSUB 5350
4750 GOTO 4540
4760 END
4820 FOR a=1 TO 39:LOCATE a,24:PRINT" ";:NEXT:RETURN
4860 REM ************************************************************Invasion
4870 z=0
4880 FOR a=1 TO f
4890 IF a=e THEN GOTO 4930
4900 IF p(a)<p(e) THEN 4930
4910 IF p(a)<1.2*(l(a)/1000) THEN 4930
4920 IF p(a)>p(z) THEN z=a
4930 NEXT
4940 IF z=0 THEN t$(0)=" Baron ":n$(0)="Bocklos von Kamikazien"
4950 IF z=0 THEN a=INT(RND*9000)+1000:GOTO 4970
4960 a=p(z)*1000-l(z)/3
4970 IF a>(l(e)-5000) THEN a=(l(e)-5000)/2
4980 CLS
4990 PRINT t$(z)" " n$(z)
5000 PRINT"marschiert in Ihr Gebiet ein"
5010 PRINT
5020 PRINT"und besetzt" a" Hektar Land !"
5030 l(z)=l(z)+a
5040 l(e)=l(e)-a
5050 z=INT(RND*40)
5051 IF z>p(e) THEN z=0
5060 PRINT
5070 PRINT t$(e)" "n$(e)" verliert " z" Soldaten im Krieg"
5080 p(e)=p(e)-z
5090 PRINT
5100 PRINT"Weiter ? Taste !"
5110 a$=INKEY$:IF a$=""THEN 5110
5130 RETURN
5140 CLS
5150 PRINT:PRINT t$(e)" "n$(e)" ist "
5160 PRINT">>>> Bankrott <<<<"
5170 PRINT
5180 PRINT"Ihr Besitz wurde zum Grossen Teil"
5190 PRINT
5200 PRINT"gepfaendet!"
5210 PRINT
5220 INPUT"Weiter ? {Enter}";a
5230 a(e)=0
5240 b(e)=0
5250 c(e)=0
5260 d(e)=0
5270 l(e)=6000
5280 u(e)=1
5290 K(e)=100
5300 m(e)=m(e)/2
5310 r(e)=5000
5320 RETURN
5330 GOSUB 5350
5340 GOTO 3570
5350 FOR a=1 TO f
5360 CLS
5370 PRINT"Dies ist die Momentane Situation im Land"
5380 PRINT"von "T$(a)" "n$(a)
5390 PRINT"Spieler" a
5400 PRINT
5410 PRINT"Adelige:.............."INT(n(a))
5420 PRINT
5430 PRINT"Soldaten:............."INT(p(a))
5440 PRINT
5450 PRINT"Kaufleute:............"INT(m(a))
5460 PRINT
5470 PRINT"Bauern:..............."INT(s(a))
5480 PRINT
5490 PRINT"Geistliche:..........."INT(q(a))
5500 PRINT
5510 PRINT"Landgroesse/Ha:......."INT(l(a))
5520 PRINT
5530 PRINT"Vermoegen/Knetis:....."INT(k(a))
5540 IF a=f THEN PRINT:PRINT"Ins Hauptmenue ? Taste"
5550 IF a=f THEN a$=INKEY$:IF a$=""THEN 5550
5560 IF a=f THEN RETURN
5570 PRINT
5580 PRINT"Naechster Spieler? Taste "
5590 a$=INKEY$:IF a$=""THEN 5590
5610 NEXT
5690 DATA Hofnarr, Baron, Graf, Minister, Premierminister, President
5700 DATA Koenig,Kaiser
5710 DATA Hofnarrin,Baroness,Graefin,Ministerin,Premierministerin
5720 DATA Presidentin,Koenigin,Kaiserin
5730 DATA Banania,Loskania,Aetzara,Kunzburg,Animalia,Magentia
6000 REM **********************************************************Krieg fuehren
6001 xz=0
6010 CLS
6020 IF p(e)<100 THEN CLS:PRINT"Mit so wenig Soldaten Kann man keinen Krieg fuehren!":CALL &BB18:GOTO 3570
6030 k(e)=k(e)-1000
6040 sg=INT(RND*5)+1
6050 es=INT(RND*5)+1
6060 z=INT(RND*40)+1
6061 YY=INT(z*19.4):xz=xz+INT(z*150.99)
6070 IF sg>es THEN PRINT"Der Gegner war zu stark!":PRINT"Sie haben "z" Soldaten verloren.":p(e)=p(e)-z:CALL &BB18:GOTO 3570
6080 IF es>sg THEN PRINT"Sie haben gesiegt!":PRINT"Sie konnten "yy" Hektar land erobern ":PRINT"und "xz"Knetis erbeuten.":PRINT"Leider haben sie "z" Soldaten verloren":l(e)=l(e)+yy:p(e)=p(e)-z:k(e)=k(e)+xz:CALL &BB18:GOTO 3570
6090 IF sg=es THEN GOTO 6010
7000 REM******************************************************************titel
7001 RESTORE
7002 ass=0
7010 FOR a=1 TO 8
7020 READ ss$(a)
7030 NEXT a
7031 RESTORE 5710
7032 FOR a=1 TO 8
7033 READ wss$(a)
7034 NEXT a
7035 note1=0:note=0
7039 note1=0:note=0
7040 IF k(e)<=1000 THEN ng(e)=6
7050 IF k(e)<=3000 AND k(e)>1000 THEN ng(e)=5
7060 IF k(e)<=5000 AND k(e)>3000 THEN ng(e)=4
7070 IF k(e)<=7000 AND k(e)>5000 THEN ng(e)=3
7080 IF k(e)<=10000 AND k(e)>7000 THEN ng(e)=2
7090 IF k(e)>=15000 THEN ng(e)=1
7100 IF l(e)<=10000 THEN nl(e)=6
7110 IF l(e)<=13000 AND l(e)>10000 THEN nl(e)=5
7120 IF l(e)<=16000 AND l(e)>13000 THEN nL(e)=4
7130 IF l(e)<=20000 AND l(e)>16000 THEN nl(e)=3
7140 IF l(e)<=25000 AND l(e)>20000 THEN nl(e)=2
7150 IF l(e)>=30000 THEN nl(e)=1
7160 IF s(e)<=2000 THEN nm(e)=6
7170 IF s(e)<=4000 AND s(e)>2000 THEN nm(e)=5
7180 IF s(e)<=8000 AND s(e)>4000 THEN nm(e)=4
7190 IF s(e)<=15000 AND s(e)>8000 THEN nm(e)=3
7200 IF s(e)<=20000 AND s(e)>15000 THEN nm(e)=2
7210 IF s(e)>=23000 THEN nm(e)=1
7220 IF p(e)<=25 THEN ns(e)=6
7230 IF p(e)<=50 AND p(e)>25 THEN ns(e)=5
7240 IF p(e)<=100 AND p(e)>50 THEN ns(e)=4
7250 IF p(e)<=150 AND p(e)>100 THEN ns(e)=3
7260 IF p(e)<=300 AND p(e)>150 THEN ns(e)=2
7270 IF p(e)>=600 THEN ns(e)=1
7280 IF u(e)<=1 THEN ni(e)=6
7290 IF u(e)<=4 AND u(e)>1 THEN ni(e)=5
7300 IF u(e)<=10 AND u(e)>4 THEN ni(e)=4
7310 IF u(e)<=15 AND u(e)>10 THEN ni(e)=3
7320 IF u(e)<=20 AND u(e)>15 THEN ni(e)=2
7330 IF u(e)>=23 THEN ni(e)=1
8000 note=note+ng(e)+nl(e)+nm(e)+ns(e)+ni(e)+le
8010 note1=note/5
8020 IF note1<=6 THEN P=1
8030 IF note1<6 AND note1>5.5 THEN P=2
8035 IF note1>5 AND note1<5.5 THEN P=3
8040 IF note1<5 AND note1>4.5 THEN P=4
8045 IF note1>4 AND note1<4.5 THEN P=5
8046 IF note1<4 AND note1>3 THEN P=6
8050 IF note1>2 AND note1<3 THEN P=7
8060 IF note1<2 THEN P=8
8070 IF p=8 THEN 4550
9001 IF t(e)=p THEN GOTO 660
9002 IF t(e)< p AND sw(e)=1 THEN t(e)=p:t$(e)=wss$(p):GOTO 4490
9010 IF t(e)< p THEN t(e)=p:t$(e)=ss$(p):GOTO 4490
9020 IF t(e)>p THEN GOTO 660
Alles anzeigen
P.S.: JavaCPC benötigt ca. 10-11 Minuten, um den Code per "Import ASCII File" einzutippern.
Solltet Ihr dennoch zu Faul sein, das alles abzutippen, aber dennoch das Spiel haben wollen, PN an mich und ich schicke ein DSK
MfG
Markus