Stern-Dreieck-Umwandlung
Die Stern-Dreieck-Umwandlung ist eine schaltungstechnische Umformung von elektrischen Widerständen. Die sind in der einen Schaltung dreieckförmig angeordnet, in der anderen sternförmig. Die Berechnung ist eintönig und, wenn manuell durchgeführt, fehlerträchtig. Deshalb gab es für so gut wie jeden programmierbaren Taschenrechner ein entsprechendes Programm.
Hier nun eine kurze Routine für ein Modell, das für solche Berechnungen eher selten benutzt wurde, den Finanztaschenrechner HP12C.
Zuerst aber ein kuzer Blick auf die allernötigsten Formeln.
Widerstände im Dreieck: R1, R2, R3
Widerstände im Stern: R12, R23, R13
1. Umwandung von Stern nach Dreieck
Die Dreieck-Widerstände berechnen sich zu
R12= 1/R3 · (R1·R2 + R1·R3 + R2·R3)
R13= 1/R2 · (R1·R2 + R1·R3 + R2·R3)
R23= 1/R1 · (R1·R2 + R1·R3 + R2·R3)
2. Umwandung von Dreieck nach Stern
Die Stern-Widerstände berechnen sich zu
R1= (R13·R12) / (R13 + R12 + R23)
R2= (R12·R23) / (R13 + R12 + R23)
R3= (R13·R23) / (R13 + R12 + R23)
Ersetzt man hier die Widerstände R durch entsprechende Leitwerte G= 1/R, erhält man:
G1= 1/G23 · (G1·G2 + G1·G3 + G2·G3)
G2= 1/G13 · (G1·G2 + G1·G3 + G2·G3)
G3= 1/G12 · (G1·G2 + G1·G3 + G2·G3)
Es fällt auf, daß die Formeln für die Widerstände im Dreieck strukturell identisch mit denen der Leitwerte des Sterns sind. Statt zwei unterschiedliche Routinen für die Umwandlng von Stern nach Dreieck bzw. von Dreieck nach Stern zu schreiben, genügt damit eine gemeinsame Routine für beide.
Für die Umwandlung von Dreieck nach Stern werden statt der Widerstände einfach die Leitwerte eingegeben. Die Routine gibt dann natürlich auch wieder Leitwerte aus. Um den entsprechenden Widerstandswert zu erhalten, genügt ein Druck auf die Taste 1/x.
Code HP12C
RCL 1 #R1|G12
RCL 2 #R2|G13
× #Term T1
RCL 2
RCL 3 #R3|G23
× #T2
+
RCL 3
RCL 1 #Stapel: T1 T2 R3 R1
× #T3
+ #konst. Klammerausdruck c
STO i #Stapelanhebung ausgeschaltet
RCL i #X: c
RCL 1
÷ #R12|G1
R/S #Ausgabe
RCL i
RCL 2
÷ #R13|G2
R/S #Ausgabe
RCL i
RCL 3
÷ #R23|G3
g GTO 00 #Ausgabe und Programmende
Alles anzeigen
(24 Programmschritte = 24 Oktett)
Beispiel
1) Von Stern nach Dreieck
R1= 5; R2= 10; R3= 15 (alle R in Ohm)
Eingabe:
5 STO 1
10 STO 2
15 STO 3
R/S
Ausgabe:
18,33 R/S
27,50 R/S
55,00
2) Von Dreieck nach Stern (Gegenprobe)
R1= 18,3333; R2= 27,5; R3= 55 (alle R in Ohm)
Eingabe:
18.33 1/x STO 1
27.5 1/x STO 2
55 1/x STO 3
R/S
Ausgabe:
0.20 1/x 5.00 R/S
0.10 1/x 10.00 R/S
0.0667 1/x 15.00
Viel Spaß beim Ausprobieren (und Portieren auf den eigenen Programmierbaren)
Thorsten