Mandelbrot auf dem Dragon 32

jedie · 11. September 2022

Auf Grundlage von Mit der Bitte um Hilfe: FRACTAL.BAS in Python? hab ich mal gesehen, ob ich ein Mandelbrot Fraktal auch auf dem Dragon 32 im Text Modus erkennbar machen kann...

Text Modus deshalb, weil mein DragonPy - 6809 Emulator für Dragon 32/64, Tandy TRS-80 Color Computer alias CoCo kein Grafikmodus beherrscht...

Rausgekommen ist:

Code

10 FOR Y=-8 TO 8
20 FOR X=-20 TO 10
30 CA=X*.1
40 CB=Y*.15
50 A=CA
60 B=CB
70 FOR I=0 TO 10
80 T=A*A-B*B+CA
90 B=2*A*B+CB
100 A=T
110 IF (A*A+B*B)>4 THEN GOTO 150
120 NEXT I
130 PRINT CHR$(128);
140 GOTO 160
150 PRINT CHR$(48+I);
160 NEXT X
170 ' RENDER NEXT LINE:
180 PRINT "!";
190 NEXT Y
200 PRINT("...RESTART...")
210 GOTO 10
220 ' Y=-8 TO 8 -> HEIGHT
230 ' X=-20 TO 10 -> WIDTH
240 ' CA=X*.1 -> ZOOM WIDTH
250 ' CB=Y*.15 -> ZOOM HEIGHT
260 ' I=0 TO 10 -> DEPTH
270 ' CHR + 48 STARTS WITH 0

Alles anzeigen

Am Ende hab ich versucht festzuhalten, welche Werte/Schleifen für was ist...

Kann man alles sicherlich optimieren... Im Kopf hab ich noch folgende Idee um die Zeichenauswahl besser als mit CHR$() zu machen:

Man könnte doch mit DATA/PEEK/POKE arbeiten: Per DATA legt man die Zeichenwerte für den Text-Scren fest sortiert nach der "Helligkeit". Die Zahlenfolge schreibt man zuerst an eine bestimmten Speicherstelle und den CHR$() ersetzt man mit einem PEEK/POKE mit einem "OFFSET+I" ... Ich vermute das ist schneller als mit READ/RESTRORE zu arbeiten?!?

Entwickelt hab ich das Listing mit meinem DragonPy Emulator und dann per RE: DWLOAD - "DriveWire for everybody" -> Datenübertragung PC <-> Dragon 32/64 auf dem echten Dragon übermittelt...

Irgendwo im Speicher legt man eine Zeichenfolge fest, von hell nach dunkel. Man hält sich per DATA fest und schreibt sie

jedie · 11. September 2022

Ha, ich habs...

Code

10 GOTO 280
20 FOR Y=-8 TO 8
30 FOR X=-21 TO 10
40 CA=X*.1
50 CB=Y*.15
60 A=CA
70 B=CB
80 FOR I=0 TO 8
90 T=A*A-B*B+CA
100 B=2*A*B+CB
110 A=T
120 IF (A*A+B*B)>4 THEN GOTO 160
130 NEXT I
140 PRINT CHR$(128);
150 GOTO 170
160 PRINT CHR$(PEEK(&H4000+I));
170 NEXT X
180 NEXT Y
190 PRINT("...RESTART...")
200 GOTO 20
210 ' Y=-8 TO 8 -> HEIGHT
220 ' X=-20 TO 10 -> WIDTH
230 ' CA=X*.1 -> ZOOM WIDTH
240 ' CB=Y*.15 -> ZOOM HEIGHT
250 ' I=0 TO 8 -> DEPTH==CHARS COUNT
260 '
270 ' INIT COLOR CHARACTERS:
280 FOR I=0 TO 8
290 READ CHARNO
300 PRINT "WRITE TO:";HEX$(&H4000+I);CHR$(CHARNO);CHARNO
310 POKE &H4000+I,CHARNO
320 NEXT I
330 GOTO 20
340 ' USED CHARACTERS:
350 DATA 128,175,191,143,223,239,159,255,207

Alles anzeigen

ThoralfAsmussen · 11. September 2022

Wie wäre es mit einem Array ? Also DATA -> DIM WERT(16) -> I=WERT(x) -> PRINT CHR$(I)

jedie · 12. September 2022

Hm. Ja vielleicht, muss ich mal bei zeiten testen, aber die CC ist ja nun vorbei...

guidol · 12. September 2022

Zitat von ThoralfAsmussen

Wie wäre es mit einem Array ? Also DATA -> DIM WERT(16) -> I=WERT(x) -> PRINT CHR$(I)

Ueber Facebook hatte ich ein weiteres FRACTAL gefunden, dass sowas enthielt.

Das Original:

Code

100 REM A BASIC, ASCII MANDELBROT
110 REM
120 REM This implementation copyright (c) 2019, Gordon Henderson
130 REM
140 REM Permission to use/abuse anywhere for any purpose granted, but
150 REM it comes with no warranty whatsoever. Good luck!
160 REM
170 C$ = ".,'~=+:;[/<&?oxOX# " : REM 'Pallet' Lightest to darkest...
180 SO = 1 : REM Set to 0 if your MID$() indexes from 0.
190 MI = LEN(C$)
200 MX = 4
210 LS = -2!
220 TP = 1.25
230 XS = 2.5
240 YS = -2.5
250 W = 64
260 H = 48
270 SX = XS / W
280 SY = YS / H
290 Q = TIME
300 FOR Y = 0 TO H
310 CY = Y * SY + TP
320 FOR X = 0 TO W
330 CX = X * SX + LS
340 ZX = 0
350 ZY = 0
360 CC = SO
370 X2 = ZX * ZX
380 Y2 = ZY * ZY
390 IF CC > MI THEN GOTO 460
400 IF (X2 + Y2) > MX THEN GOTO 460
410 T = X2 - Y2 + CX
420 ZY = 2 * ZX * ZY + CY
430 ZX = T
440 CC = CC + 1
450 GOTO 370
460 PRINT MID$(C$, CC - SO, 1);
470 NEXT
480 PRINT
490 NEXT
500 PRINT
510 PRINT (TIME - Q) / 100
520 END

Alles anzeigen

und das abgeaenderte FRACTAL.BAS, dass nun auch dieses "Array" nutzt:

Code

5 DIM C$(20)
10 C$ = ".,'~=+:;[/<&?oxOX# " : REM 'Pallet' Lightest to darkest...
20 FOR Y=-12 TO 12
30 FOR X=-39 TO 39
40 CA=X*.0458
50 CB= Y*.08333
60 A=CA
70 B=CB
80 FOR I=0 TO 15
90 T=A*A-B*B+CA
100 B=2*A*B+CB
110 A=T
120 IF (A*A+B*B)>4 THEN GOTO 160
130 NEXT I
140 PRINT " ";
150 GOTO 190
160 IF I>9 THEN I=I+7
170 REM PRINT CHR$(48+I);
180 PRINT MID$(C$, I+1, 1);
190 NEXT X
200 PRINT
210 NEXT Y

Alles anzeigen

ThoralfAsmussen · 12. September 2022

Code

out = ".,'~=+:;[/<&?oxOX# "
    
for y in range (-15, 15+1):
    
    for x in range (-39, 39+1):
        ca = float(x*0.0458)
        cb = float(y*0.08333)
        a = ca
        b = cb
        
        for i in range (0, 15+1):
            t = a*a-b*b+ca
            b = 2*a*b+cb
            a = t
            z = a*a+b*b
            if z > 4:
                print out[i],
                break
        
        if z <= 4: print " ",

    print

Alles anzeigen

daybyter · 13. September 2022

Kennst Du das hier?

XRoar, a Dragon and Tandy 8-bit computer emulator

Könnte man damit nicht auch ein Grafik Mandelbrot rendern?

ThoralfAsmussen · 13. September 2022

Klar.

Nur die Auflösung ist dann nicht so wirklich hoch.

Tags