Hallo,
kann mir jemand sagen, wo ich Woz' "Breakout"-Spiel finden kann? Als BASIC-Listing oder als Disk-Image-Datei.
Danke!!
µP
Hallo,
kann mir jemand sagen, wo ich Woz' "Breakout"-Spiel finden kann? Als BASIC-Listing oder als Disk-Image-Datei.
Danke!!
µP
Sieben Minuten von der Frage bis zur Antwort... Gab's da nicht ein Googledrive, wo das Listing lag
grins
Sieben Minuten von der Frage bis zur Antwort... Gab's da nicht ein Googledrive, wo das Listing lag
grins
Weil ich keine Paddles habe, muss ich das morgen erst mal auf Tastaturbetrieb umschreiben. Das Seminar fängt um 12 Uhr an ... mal schauen, wie schnell ich bin.
Ach, das sind ja noch 18 Stunden. Das schaffst du ...
Paddles kannst Du ganz leicht selbst bauen: pro Paddle ein 150 kOhm Poti, einen Taster, einen Widerstand zwischen 570 Ohm und 1KOhm und etwas 3-adriges Kabel, und pro Set noch eine 16 pol. IC Fassung. Die Potis zwischen +5 V (rechter oder linker Anschluss des Poti) und GC0 bzw. GC1 an den mittleren Anschluß. Die Taster über +5 V mit PB0 bzw. PB1 verbinden. PB0/1 werden von den 1kOhm Widerständen mit GND verbunden - fertig.
Einen Schaltplan findest Du auf: http://www.atariarchives.org/ccc/chapter1.php (ja, für die Apple II Paddles !)
Weiß denn jemand wo man ein Listing finden kann?
Listing für Breakout?
Einfach das DSK-File von Asimov herunterladen, dann mit z.B. AppleWin oder CiderPress öffnen und auslesen
Wurde von Steve in Integer Basic geschrieben.
10 TEXT : CALL -936: VTAB 4: TAB 10: PRINT "*** BREAKOUT ***": PRINT : PRINT " OBJECT IS TO DESTROY ALL BRICKS": FOR N=1 TO 3000: NEXT N
20 DIM A$(15),B$(10): GR : PRINT : INPUT "HI, WHAT'S YOUR NAME? ",A$:A=1:B=13:C=9:D=6:E=15: PRINT "STANDARD COLORS, ";A$;
30 INPUT "? ",B$: IF LEN(B$)=0 THEN 60: IF B$(1,1)#"N" THEN 60: FOR I=0 TO 39: COLOR= I/2*(I<32): VLIN 0,39 AT I
40 NEXT I: POKE 34,20: PRINT : PRINT : PRINT : FOR I=0 TO 15: VTAB 21+I MOD 2: TAB I+I+1: PRINT I;: NEXT I: POKE 34,22: VTAB 24: PRINT : PRINT "BACKGROUND";
50 GOSUB 170:A=E: PRINT "EVEN BRICK";: GOSUB 170:B=E: PRINT "ODD BRICK";: GOSUB 170:C=E: PRINT "PADDLE";: GOSUB 170:D=E: PRINT "BALL";: GOSUB 170
60 POKE 34,20: COLOR= A: FOR I=0 TO 39: VLIN 0,39 AT I: NEXT I: FOR I=20 TO 34 STEP 2: TAB I+1: PRINT I/2-9;: COLOR= B: VLIN 0,39 AT I: COLOR= C: FOR J=I MOD 4 TO 39 STEP 4
70 VLIN J,J+1 AT I: NEXT J,I: TAB 5: PRINT "SCORE = 0": PRINT : PRINT : POKE 34,21:S=0:P=S:L=S:X=19:Y=19:L=6
80 COLOR= A: PLOT X,Y/3:X=19:Y= RND (120):V=-1:W= RND (5)-2:L=L-1: IF L<1 THEN 510: TAB 6: IF L>1 THEN PRINT L;" BALLS LEFT"
90 IF L=1 THEN PRINT "LAST BALL, ";A$: PRINT : FOR I=1 TO 100: GOSUB 1000: NEXT I:M=1:N=0
100 J=Y+W: IF J>=0 AND J<120 THEN 110:W=-W:J=Y: FOR I=1 TO 6:K= PEEK (-16336): NEXT I
110 I=X+V: IF I<0 THEN 1200: GOSUB 1000: COLOR= A:K=J/3: IF I>39 THEN 130: IF SCRN( I,K)=A THEN 150: IF I THEN 180:N=N+1:V=(N>5)+1:W=(K-P)*2-5:M=1
120 Z= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336): GOTO 150
130 FOR I=1 TO 6:M= PEEK (-16336): NEXT I:I=X:M=0
140 V=-V
150 PLOT X,Y/3: COLOR= E: PLOT I,K:X=I:Y=J: GOTO 100
160 PRINT "INVALID. REENTER";
170 INPUT " COLOR (0 TO 15)",E: IF E<0 OR E>15 THEN 160: RETURN
180 IF M THEN V= ABS (V): VLIN K/2*2,K/2*2+1 AT I:S=S+I/2-9: VTAB 21: TAB 13: PRINT S
190 Q= PEEK (-16336)- PEEK (-16336)+ PEEK (-16366)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
200 IF S<720 THEN 140
500 PRINT "CONGRATULATIONS, ";A$;" YOU WIN!": GOTO 600
510 PRINT "YOUR SCORE OF ";S;" IS ";: GOTO 520+(S/100)*10
520 PRINT "TERRIBLE!": GOTO 600
530 PRINT "LOUSY.": GOTO 600
540 PRINT "POOR.": GOTO 600
550 PRINT "FAIR.": GOTO 600
560 PRINT "GOOD.": GOTO 600
570 PRINT "VERY GOOD.": GOTO 600
580 PRINT "EXCELLENT.": GOTO 600
590 PRINT "NEARLY PERFECT."
600 PRINT "SAME COLORS, ";A$;: GOTO 30
1000 Q=( PDL (0)-20)/6: IF Q<0 THEN Q=0: IF Q>=34 THEN Q=34: COLOR= D: VLIN Q,Q+5 AT 0: COLOR= A: IF P>Q THEN 1100: IF Q THEN VLIN 0,Q-1 AT 0:P=Q: RETURN
1100 IF P=Q THEN RETURN : IF Q#34 THEN VLIN Q+6,39 AT 0:P=Q: RETURN
1200 FOR I=1 TO 80:Q= PEEK (-16336): NEXT I: GOTO 80
Alles anzeigen
Kann ich das auf einen //e einfach so eingeben?
vorher auf Integer Basic wechseln und dann einfach eintippen.
so, das läuft nicht. warum? Breakout.cass.zip
Und wer soll das evtl. ansehen können ?? - das ist ein Soundfile und kein Basictext.
Das kann ich dir nicht sagen, Telexer.
Wichtig noch einmal: integerbasic muss aktiviert werden (ich weiß allerdings nicht mehr, ob du dass vor dem Laden von Kassette machen musst, oder anschließend machen kannst).
Lesen von Tape ist verbunden mit Fehlermoglichkeiten (zu laut, zu leise)
Warum tippst du die paar Zeilen nicht einfach ab? Dann kannst du noch ein paar Kleinigkeiten lernen. So WAV lade und aufspielen ist sooo 2010
Viel Erfolg