Parameterabfrage in CP/M...

dskfmt    equ    0f03fh
bootstp   equ    0f000h
bdos      equ    05h
wrt       equ    09h
;
        org 0100h
        di
        lxi sp,stack
        xra a
;
        mvi c,wrt
        lxi d,text
        call bdos 
;
        call pmter
        cpi "A"
        jz fmta
        cpi "B"
        jz fmtb
        cpi " "
        jz end
;
fmta    mvi c,0
        call dskfmt
        jmp end
fmtb    mvi c,1
        call dskfmt
        jmp end
;
end     lxi h,bootstp
        push h
;             
 
pmter    ; Hier soll die Abfrageroutine stehen, die den 
         ; Laufwerksbuchstabe aus dem Zeilenpuffer nach dem
         ; Aufruf von format.com durchführt. Dementsprechend wird
         ; dann 0 oder 1 in den Akku geschrieben..      
;
        hlt
;
;
text    db "Formatierprogramm für 8" SSSD-Disketten $"
        ds 0ffh        ; 1 page für stack
stack   ds  01h        ; Start stack (rückwärts - 1 page reserved)

;
;
;
;    Diskettenformatierprogramm 
;    
;    für Jan´s IMSAI 8080
;
;    Syntax: FORMAT_[Laufwerksbuchstabe A oder B]:
;

unit        equ    042h        ; Hier erwartet der Floppycontroller das Lwk
dskfmt        equ    0f03fh        ; Disk-Formatierroutine im Eprom
dskhme        equ    0f0b3h        ; Disk home, gehe zu Track 00, Sektor 01        
bdos          equ    05h        ; Hier steht die BDOS-Einsprungadresse
wrt           equ    09h        ; BDOS Funktion 9 Writestring
cread        equ    01h        ; BDOS Funktion "auf Tastendruck warten!
buff        equ    080h        ; Buffer der Parameter Startadresse
drive        equ    buff+2        ; Hier wird die Benennung des Ziellaufwerkes erwartet !
colon        equ    buff+3        ; Hier wird der Doppelpunkt erwartet !
    
;
        org 0100h        ; Programmstart
        di            ; Interrupts ausschalten
;        lxi h,0            ; HL Register löschen
        dad sp            ; Alten Stackpointer zu HL addieren und somit reinschreiben
        shld oldsp        ; Alten Stackpointer in definiertem Speicher sichern
;    
        lxi sp,stack        ; Neuen Stack für dieses Programm definieren
        xra a            ; Akku löschen
;
        mvi c,wrt        ; BDOS Funktion 9 WRITESTR in Reg C
        lxi d,text        ; Dementsprechend Begrüßungstext laden
        call bdos         ; BDOS aufrufen, um Text aus zu geben
;
        call pmter        ; Rufe Parameterroutine zur Bestimmung des Laufwerks
        cpi "A"            ; Befindet sich ein "A" im Akku, wenn ja, dann
        jz fmta            ; Rufe Routine zur Formatierung Lwk A:
        cpi "B"            ; Befindet sich ein "B" im Akku, wenn ja, dann
        jz fmtb            ; Rufe Routine zur Formatierung Lwk B:
        cpi " "            ; Steht da nichts, dann
        jmp error        ; springe zur Fehler-Routine
;
fmta    call rusre        ; Are you sure ???
        mvi c,0            ; 0 für Lwk A in Reg C und
        call dskfmt        ; Formatierroutine im EPROM aufrufen        
        jmp end            ; Programmende
;
fmtb    call rusre        ; Are you sure ???
        mvi c,1            ; 1 für Lwk B in Reg C und
        call dskfmt        ; Formatierroutine im Eprom aufrufen        
        jmp end            ; Programmende
;    
pmter    lda colon        ; Befindet sich da ein Doppelpunkt ???        
        cpi ":"
        jnz error        ; Wenn nicht, springe zur Fehler-Routine
        lda drive        ; Andernfalls lade eine Speicherstelle vorher den Parameter
        ret
;
rusre    mvi c,wrt        ; BDOS Funktion 9 WRITESTR in Reg C
        lxi d,caution        ; "Sind Sie sicher"-Text laden
        call bdos        ; BDOS aufrufen, um Text aus zu geben
        mvi c,cread        ; Warte auf Eingabe von Tastatur.. Eingabe geht über in Akku
        call bdos
        cpi "y"            ; Ist die Eingabe Y ?
        rz                ; Wenn ja, return from subroutine
        cpi "n"            ; Ist die Eingabe N ?
        jz end            ; Beende das Programm.
        jnz rusre        ; Bleibe in Schleife bei ungültiger Eingabe        
;
error    mvi c,wrt        ; BDOS Funktion 9 WRITESTR in Reg C
        lxi d,derror        ; Fehlertext laden
        call bdos        ; BDOS aufrufen, um Text aus zu geben
        jmp end2        ; Programmende

end     call dskhme        ; Laufwerk neu initialisieren
        mvi c,wrt        ; BDOS Funktion 9 WRITESTR in Reg C
        lxi d,ida        ; "Insert CP/M Disk in Drive A:"
                        ; und drücke RETURN
        call bdos        ; BDOS aufrufen, um Text aus zu geben
wait    mvi c,cread        ; Warte auf Tasteneingabe...Eingabe geht über in Akku
        call bdos
        cpi 0dh            ; Return gedrückt ?
        jz end2            ; Wenn ja, springe zu end2
        jnz wait        ; Wenn nicht, bleibe in der Endlosschleife
end2    lhld oldsp        ; Hole Wert von altem Stackpointer aus dem Speicher
        sphl            ; und schreibe ihn wieder in den Stackpointer
        xra a            ; Lösche Akku
        sta unit        ; Zeropage diskselect für Floppycontroller
        call dskhme        ; Initialisiere Laufwerk, gehe zu Track 00, Sektor 01
        jmp 0            ; Springe zu CP/M Einsprungadresse
;             

        hlt            ; Programmende
;
;
text    db 0ah,0ah,0dh
    db "IMSAI FL"
    db "OPPY FOR"
    db "MAT ROUT"
    db "INE 8 IN"
    db "CH SSSD "
    db "$"
derror    db 0ah,0ah,0dh
    db "INVALID "
    db "DRIVE OR"
    db " PARAMET"
    db "ERS !!! "
    db 0ah,0ah,0ah,0dh
    db "$"
caution    db 0ah,0ah,0dh
    db "FORMATTI"
    db "NG WILL "
    db "ERASE AL"
    db "L DATAS "
    db "! Are yo"
    db "u sure ?"
    db " (Y/N) $"
ida    db 0ah,0ah,0dh
    db "INSERT C"
    db "P/M-DISK"
    db " IN DRIV"
    db "E A:"
    db 0ah,0dh
    db "AND PRES"
    db "S RETURN"
    db " !"
    db 0ah,0ah,0ah,0dh
    db "$"
;
        ds 0ffh        ; 1 page für stack
stack   ds  01h        ; Start stack (rückwärts - 1 page reserved)
oldsp    ds  02h           ; alter Stackpointer